set("log.file",false)
set("log.stdout",true)

set("server.telnet",true)
set("server.telnet.port", 5000)
set("server.telnet.bind_addr", "0.0.0.0")

set("decoder.file_extensions.gstreamer",["wav", "webm"])
set("decoder.mime_types.gstreamer",["audio/x-wav", "audio/wav", "video/webm"])

def crossfade(a,b)
  add(normalize=false,
      [ sequence([ blank(duration=5.),
                   fade.initial(duration=5.,b) ]),
        fade.final(duration=5.,a) ])
end

live = audio_to_stereo(
    rewrite_metadata(
        [
            ("title", "$(title) (LIVE - Dodsorfas Radio)"),
            ("comment", "http://www.radio.dodsorf.as")
            ],
        stretch(
            ratio=interactive.float("test", 1.00005),
            input.harbor(
                "dodsorfas.live",
                id="dodsorfas.live",
                port=5002,
                password=getenv("LIVE_PASSWORD"),
                user="source",
                logfile="/tmp/harbor.log"
                )
            )
        )
)

DanDubstepThingies	= "/playlists/Daniel/Dan - dubstepthingies.m3u"

randomsong = playlist(conservative=true, DanDubstepThingies)
count = list.length(playlist.parse(DanDubstepThingies))

randomsong = audio_to_stereo(randomsong)
requests = audio_to_stereo(drop_video(request.queue(id="request")))

mix = blank()
mix = fallback(track_sensitive=false, [randomsong, mix])
mix = fallback(track_sensitive=true, transitions=[crossfade], [requests,mix])
mix = fallback(track_sensitive=false, transitions=[crossfade], [live, mix])
mix = normalize(mix)

# OUTPUTS
output.icecast(
    password=getenv("HARBOR_PASSWORD"),
    host=getenv("BROADCAST_PORT_5001_TCP_ADDR"),
    port=int_of_string(getenv("BROADCAST_PORT_5001_TCP_PORT")),
    %wav,
    mount="dodsorfas.main",
    mix
    )